Programming an Extended Range Dynamic Power Measurement

Programming an Extended Range Dynamic Power Measurement

Last updated: January 16, 2009

This section provides an example of how to make an Extended Range Dynamic Power measurement via remote program.

The following program example assumes that the test set is in Active Cell Operating mode and the UE is connected to the RF IN/OUT connector.

The basic procedure to make the Extended Range Dynamic Power measurement is as follows:

  1. Set the test set's receiver to the proper power and frequency using the RFANalyzer:CONTrol:POWer:AUTO , RFANalyzer:MANual:POWer[:SELected] and RFANalyzer:MANual:MEASurement[:MFRequency] commands.
  2. Set the parameters (see Extended Range Dynamic Power Measurement Parameters for details) to match your UE's output power sequences and trigger source requirement using the SETup:WEDPower commands. In this example, an RF rise trigger is used.
  3. Place your UE into the test mode and verify that it is ready for measurement.
  4. Order your UE to transmit so that the first power step in the power sequences meets the requirements of the RF rise trigger. The trigger pulse should rise in power by at least 20 dB and above the RF Rise Trigger Threshold level. See Triggering the Extended Range Dynamic Power Measurement for details.
  5. Initiate (arm) the Extended Range Dynamic Power measurement using the INITiate:WEDPower command.
  6. Send the INITiate:WEDPower:ARMed? query and wait for it to return a value of 1, indicating that the measurement is armed and ready to be triggered
  7. Order your UE to begin transmission of its power sequences (two power sequences for measurement and 15 timeslots of constant power in the middle of the two power sequences for test set re-ranging. The test set does not make any measurement during the receiver re-ranging period).
  8. When the measurement completes, use the FETCh:WEDPower commands to obtain the measurement results for each step.

Programming Example

 
10 CLEAR SCREEN
20 OPTION BASE 0
30 Testset=718
40 !
50 ! *** Variable declarations for the measurements ***
60 DIM Edpow_res$[5000]
70 DIM Dynamic_val(200)
80 !
90 Fst_seq_steps=45      ! Number of steps in 1st sequence
100 Sec_seq_steps=40     ! Number of steps in 2nd sequence
110 Meas_freq=1000000000 ! Frequency = 1GHz
120 Man_pwr=13           ! Manual Power = 13 dBm
130 Sec_seq_exp_pwr=-32  ! Second sequence expected power = -32 dBm.
140 Trig_source$="Rise"  ! Trigger Source is RF Rise.
150 Trig_thresh=3        ! RF rise trigger threshold = 3dBm
160                       ! (10 dB below the manual power)
170 !
180 !***Set up measurement parameters***
190 !
200 OUTPUT Testset;"SETup:WEDPower:TIMeout 10"
210 ! Sets Measurement Timeout to 10 seconds
220 OUTPUT Testset;"RFANalyzer:MANual:MEASurement ";Meas_freq
230 ! Sets Measurement Frequency to 1 GHz (output from UE)
240 OUTPUT Testset;"RFANalyzer:CONTrol:POWer:AUTO OFF"
250 ! Sets Power Control to manual mode
260 OUTPUT Testset;"RFANalyzer:MANual:POWer ";Man_pwr
270 ! Sets the maximum expected power output from the UE. It is used by
280 ! test set to range its receiver for initial test. It is recommended
290 ! that you set it to the first step in the first power sequence of UE output.
300 OUTPUT Testset;"SETup:WEDPower:SSEQuence:EXPected:POWer ";Sec_seq_exp_pwr
310 ! Sets second sequence expected power. Test set requires re-ranging its
320 ! receiver based on this setting for the second sequence test.
330 !
340 OUTPUT Testset;"SETup:WEDPower:STEPs:FSEQuence ";Fst_seq_steps
350 ! Sets number of power steps in first sequence.
360 OUTPUT Testset;"SETup:WEDPower:STEPs:SSEQuence ";Sec_seq_steps
370 ! Sets number of power steps in second sequence.
380 !
390 OUTPUT Testset;"SETup:WEDPower:TRIGger:SOURce ";Trig_source$
400 ! Sets trigger source.
410 OUTPUT Testset;"SETup:WEDPower:TRIGger:THReshold ";Trig_thresh
420 ! Sets RF rise trigger threshold.
430 !
440               !
450 !***Initiate the measurement***
460 !
470 OUTPUT Testset;"INITiate:WEDPower"
480 ! Initiates the measurement
490 OUTPUT Testset;"INIT:WEDPower:ARMed?"
500 !Queries whether the measurement is ready for trigger.
510 ENTER Testset;Meas_arm
520 IF Meas_arm THEN
530   PRINT "Command the UE to trigger the measurement and begin its step down"
540   PRINT "power sequences (two power sequences for measurement and 15 timeslots"
550   PRINT "of constant power in the middle of the two power sequences"
560   PRINT "for test set re-ranging its receiver.  Test set does not make"
570   PRINT "any measurement during the receiver re-ranging period.)"
580   PRINT
590  LINPUT "Press ENTER when finished",Keyboard$
670  !***Obtain measurement results***
680  OUTPUT Testset;"FETCh:WEDPower?"
690  ENTER Testset;Integrity,Numpowmeas,Edpow_res$
700  ! Fetches the integrity indicator, the number of power
710  ! steps measured and power results for each step.
770 ELSE
780   PRINT "The test set is not properly armed. Please check the setups."
790   GOTO End_program
800 END IF
810 !
820 !***Print measurement results***
830 PRINT
840 PRINT "Integrity Indicator = ";Integrity
850 PRINT "The number of power meas results available = ";Numpowmeas
860 FOR I=1 TO Numpowmeas
870   Dynamic_mkr=((I-1)*17)
880   ! Sets up a marker that will jump to each comma in the ascii string
890   Dynamic_val(I)=VAL(Edpow_res$[Dynamic_mkr+1;Dynamic_mkr+16])
900   ! Convert ascii to a numeric value
910   PRINT
920   PRINT "Power of step";I;"= ";Dynamic_val(I);"dBm/5 MHz"
930 NEXT I
940 !
950 !*******************************************************************
960 ! Subroutine: End of all testing clean up
970 !*******************************************************************
980 !
990  End_program:!
1000 !
1010 OUTPUT Testset;"*RST"
1020 !Full preset test set
1050 PRINT "End of Program"
1060 END

Part of the results from this example program is shown below:

Related Topics

Extended Range Dynamic Power Measurement Description

Manual Operation: How Do I Make an Extended Range Dynamic Power Measurement?

Extended Range Dynamic Power Measurement Troubleshooting

Receiver Control